# Maintainer: Astro Benzene <universebenzene at sina dot com>
pkgname=python-sherpa
pkgver=4.9.1
pkgrel=1
pkgdesc="Modeling and fitting package for scientific data analysis"
arch=('i686' 'x86_64')
url="http://cxc.cfa.harvard.edu/contrib/sherpa/"
license=('GPL')
depends=('python>=3.5' 'python-numpy' 'python-astropy')
makedepends=('python-setuptools' 'gcc-fortran')
optdepends=('python-matplotlib: Graphical output'
            'python-pytest>=3.3: For testing suite'
            'python-mock: For testing suite'
            'python-pytest-xvfb: For testing suite')
source=("https://files.pythonhosted.org/packages/source/s/sherpa/sherpa-${pkgver}.tar.gz")
md5sums=('bc86d545e5d7764b1601e7fe0d8e76a6')

build() {
  export LDFLAGS="$LDFLAGS -shared"
  cd ${srcdir}/sherpa-${pkgver}

  python setup.py build
}

package() {
  export LDFLAGS="$LDFLAGS -shared"
  cd ${srcdir}/sherpa-${pkgver}

  python setup.py install --root=${pkgdir} --prefix=/usr --optimize=1
  install -D -m644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
}