# Maintainer: Médéric Boquien <mboquien at free dot fr>
# Contributor: Astro Benzene <universebenzene at sina dot com>

pkgname=python-pyregion
pkgver=2.1.1
pkgrel=1
pkgdesc="A python module to parse ds9 and ciao region files"
arch=('i686' 'x86_64')
url="https://pyregion.readthedocs.io"
license=("MIT")
depends=('python-pyparsing>=2.0' 'python-astropy>=1.0' 'cython')
makedepends=('python-setuptools' 'python-astropy-helpers<3.2')
checkdepends=('python-pytest-astropy' 'python-matplotlib')
source=("https://files.pythonhosted.org/packages/source/p/pyregion/pyregion-${pkgver}.tar.gz")
sha512sums=('ae62218f3059c46bda2d168843004025a39af6f335be5ffb618a9eecfa27430eba185d619e988bfdb95bdddf84f4de07a45bd83e641a1f2792e36c039d165a58')

prepare(){
    cd ${srcdir}/pyregion-${pkgver}

    sed -i -e '/auto_use/s/True/False/' setup.cfg
    export _pyver=$(python -c 'import sys; print("%d.%d" % sys.version_info[:2])')
}

build() {
    cd ${srcdir}/pyregion-${pkgver}

    python setup.py build --use-system-libraries --offline
}

check() {
    cd ${srcdir}/pyregion-${pkgver}

    pytest "build/lib.linux-${CARCH}-${_pyver}" || warning "Tests failed"
}

package() {
    cd ${srcdir}/pyregion-${pkgver}

    install -D -m644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
    install -D -m644 -t "${pkgdir}/usr/share/doc/${pkgname}" README.rst
    python setup.py install --root=${pkgdir} --prefix=/usr --optimize=1 --use-system-libraries --offline
}