pkgname=rocksdb
pkgver=5.14.2
pkgrel=1
pkgdesc='Embedded key-value store for fast storage'
arch=(i686 x86_64 armv7h)
url='http://rocksdb.org'
license=(Apache leveldb)
depends=(
'bzip2'
'gcc-libs'
'lz4'
'snappy'
'zlib'
)
makedepends=('gcc' 'make')
checkdepends=(python2)
source=(https://github.com/facebook/rocksdb/archive/v$pkgver.zip
"fix3870.patch::https://github.com/facebook/rocksdb/commit/e5ae1bb46564689e56a38f3509daffa4aca3b29c.patch")
sha256sums=('15bb12b9492fc2a20c0c4dbd8873703a1b6b620c32708aaaf558b0a4f58feeda'
'0f92592afece0a0ad743721472a1d5a8c714d7564463db04c547382cf40454d9')
prepare() {
cd rocksdb-$pkgver
sed -e 's/\bpython\b/python2/' -i Makefile
if [ "$CARCH" == "armv6h" ]; then
sed -e 's/-momit-leaf-frame-pointer//' -i Makefile
fi
patch -Np1 <../fix3870.patch
}
build() {
cd rocksdb-$pkgver
make shared_lib -j4
}
#check() {
# cd rocksdb-rocksdb-$pkgver
# make check
#}
package() {
cd rocksdb-$pkgver
install -d "$pkgdir"/usr/include
cp -r include/rocksdb "$pkgdir"/usr/include
install -m755 -D librocksdb.so "$pkgdir"/usr/lib/librocksdb.so
install -D -m644 LICENSE.Apache "$pkgdir/usr/share/licenses/$pkgname/LICENSE.Apache"
install -D -m644 LICENSE.leveldb "$pkgdir/usr/share/licenses/$pkgname/LICENSE.leveldb"
}