# Maintainer: Vojtech Kral <vojtech_kral^hk>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Kuba Serafinowski <zizzfizzix(at)gmail(dot)com>

pkgname=kdeconnect-git
pkgver=r2641.6baa2ff9
pkgrel=1
pkgdesc='Adds communication between KDE and your smartphone'
arch=(i686 x86_64)
url='https://community.kde.org/KDEConnect'
license=(GPL2)
depends=('hicolor-icon-theme' 'kde-cli-tools' 'kio' 'kwayland' 'libfakekey' 'pulseaudio-qt' 'qca-qt5' 'kirigami2' 'kpeople')
makedepends=(extra-cmake-modules git python)
optdepends=('sshfs: remote filesystem browser')
provides=(kdeconnect)
conflicts=(kdeconnect-frameworks kdeconnect)
source=("git://anongit.kde.org/kdeconnect-kde.git"
"fix-ecm.patch::https://cgit.kde.org/kdeconnect-kde.git/patch/?id=dedb4b1ed216a22eaedb33c114f3a30fea67839d")
install=$pkgname.install
sha256sums=('SKIP'
            '7db7d37e0fb2e82103624738253c2cb32fa1671dc9e16c43d6d9031bca67b380')

pkgver() {
  cd kdeconnect-kde
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
  cd kdeconnect-kde
  #patch -Rp1 -i ../fix-ecm.patch
}

build() {
  cd build
  cmake ../kdeconnect-kde \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DLIB_INSTALL_DIR=lib \
    -DLIBEXEC_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}